How to add Pass Phrase to users in ACF2 using ACFSVC calls - sample code
Article ID: 231732
Updated On:
Products
ACF2 - z/OS
Issue/Introduction
Is there sample code to add a pass phrase for a user?
Environment
Release : 16.0
Component : ACF2 for z/OS
Resolution
********************************* TOP OF DATA ********************* 00002801
* HOW TO APPLY A PASSWORD PHRASE VIA ACFSVC... 00002901
* 00003001
* SYS1.MACLIB (FOR YREGS) AND CAI.CAIMAC ARE REQUIRED FOR ASSEMBLY. 00003101
* 00003201
* 00007001
ACNTRY , 00008001
ACCVT , 00009001
ACARE TYPE=XARE WE DON'T ACTUALLY USE XARES 00010001
PHRASCHG CSECT 00020001
LR R12,R15 00030001
USING PHRASCHG,R12 00040001
ACFINCVT R15,NONE=XN85ACFNOTACTIVE DOESN'T NEED THIS 00080001
ST R15,WRK_ACF2CVT SAVE ACCVT ADDRESS LOCALLY 00100001
LA R9,WORKA 00140003
USING ACNTRY,R9 00150003
MVI ACNTFCN,ACNTFC0A INFOSTOR ACCESS & UPDATE 00160001
MVI ACNTSFCN,ACNF$FIN FORMATTED INSERT 00170007
MVI ACNTFLGC,0 NO FLGC 00180001
LHI R1,-1 USE 00190001
ST R1,ACNTUCB ACF2 SUPERCALL 00200001
LA R15,MSG 00210001
ST R15,ACNTMSG 00220001
MVI ACNTFLG2,0 NO FLG2 00230001
MVC ACNTTYPE,=CL4'PUSR' STORAGE CLASS & TYPE 00240001
MVC ACNTSIRI,=CL40' ' INIT KEY TO BLANKS 00250001
MVC ACNTSIRI(8),=CL8'PWPHRASE' FIELD NAME TO KEY 00260001
MVC ACNTSIRI+8(8),USERID USERID TO KEY 00270001
* 00280001
SR R15,R15 00290001
ST R15,ACNTRSBA DON'T SUPPLY RSB POINTER 00300001
* 00310001
LA R15,WRK_ARE_PASSWORD 00320001
ST R15,ACNTAREB @ACARE TO ACNTRY 00330001
LHI R15,L'WRK_ARE_PASSWORD 00340001
ST R15,ACNTAREL LENGTH OF PWPHRASE ARE 00350001
LHI R15,8 LENGTH OF PRIMARY 00360001
STH R15,ACNTPSIL SYSID 00370001
STH R15,ACNTPRIL AND RECID 00380001
MVI ACNTFLGV,ACNV$APP+ACNV$SID+ACNV$RID 00390001
MVI ACNTCNTL,ACNTNRET DO NOT RETURN FORMATTED REC 00410001
MVI ACNTFLGM,ACNM$PWP MAGIC FLAG FOR LID MODE... 00420001
DROP R9 00430001
LA R9,WRK_ARE_PASSWORD 00450001
USING ACARE,R9 00460001
USING AREXVSEC,AREOBASE NOT USING XARES 00470001
XC WRK_ARE_PASSWORD,WRK_ARE_PASSWORD 00480001
LHI R15,PHRASEL GET PHRASE LENGTH 00490001
STH R15,AREVLNTH SAVE IT 00500001
LA R14,PHRASE SOURCE 00510001
LA R0,AREVALUE TARGET 00520001
LHI R1,(L'WRK_ARE_PASSWORD)-AREBLNTH TARGET LEN 00530001
MVCL R0,R14 COPY IT 00540001
LHI R15,L'WRK_ARE_PASSWORD LENGTH OF WHOLE ARE 00550001
STH R15,ARELNTH 00560001
MVI ARECFLG,ARECREP REPLACE CHARACTER FIELD 00570001
MVC AREANAME,=CL8'PWPHRASE' 00580001
MVI AREFLGS,AREFEND THIS IS THE LAST ARE 00590001
DROP R9 00600001
* 00610001
* 00620001
L R8,WRK_ACF2CVT 00630001
USING ACCVT,R8 00631001
ACFSVC ACFSVC WORKA,TYPE=A,CVT=HAVE 00632001
DROP R8 00633007
*** 00634007
*END OF EXAMPLE CODE 00635007
**** 00636007
DS 0D 00637104
XN85ACFNOTACTIVE EQU * 00638007
* 00639001
* CONSTANTS 00639101
* 00639201
DS 0D 00639301
USERID DC CL8'USER001 ' 00639407
* 00639501
PHRASE DC C'THISISAFAIRLYLONGPHRASE123$' THE PHRASE 00639601
PHRASEL EQU *-PHRASE ITS LENGTH 00639701
* 00639801
LTORG , 00639901
* 00640001
* 00640101
* UPDATED DATA (NON RENT FOR CONVENIENCE) 00640201
* 00640301
WRK_ARE_DATA DS 0F 00640401
WRK_ARE_PASSWORD DS XL(AREBLNTH+100) 00640501
* 00640601
WRK_ACF2CVT DC A(0) 00640701
* 00640801
MSG DS 0CL128 <-| 00640901
DC 64X'ABCD' <-| INIT TO RECOGNIZABLE PATTERN 00641001
00641101
WORKA DC 512X'0000' PRE-ZEROED 00641201
* 00641301
* 00641401
YREGS , 00641501
END PHRASCHG 00641601
Additional Information
This sample code is provided without any warranty that it will work in your environment
Use of this code is purely at your own risk.
It is recommended that you review the code and adjust as required.
This code sample is NOT supported by Broadcom
Feedback
Yes
No
Powered by
