HP DC5850 reboots continuously in PXE MS-DOS boot process

Products

• Deployment Solution

Issue/Introduction

HP DC5850 reboots continuously in PXE MS-DOS boot process.

Cause

End of autoexec.bat > dreboot.exe has a '-hard' command line for the reboot. The reset command for this particular motherboard.

Resolution

1. Place a –rs switch after the bootwork.exe command in the autoexec.bat file of the MS-DOS boot image.

2. Create a New MS-DOS Boot image for Only the HP DC5850. Replace the Autoexec.bat within the MSDOS PXE automation with this one below. Regenerate the MS-DOS managed Boot image. 

@echo off

REM ==============================================================
REM Altiris Variables
REM
REM ALTIRIS_BOOTDEVICE can be one of: USB PXE CDROM DVD HBW EBW FLOPPY
REM ALTIRIS_BOOTTYPE can be one of: NETWORK AUTOMATION
REM --------------------------------------------------------------

SET ALTIRIS_BOOTDEVICE=$$ALTIRIS_BOOTDEVICE$$
SET ALTIRIS_VER=$$ALTIRIS_VER$$
SET ALTIRIS_BOOTTYPE=$$ALTIRIS_BOOTTYPE$$
SET ALTIRIS_SHARE=$$SHARE$$

 

REM ==============================================================
REM Run the keyboard/screen lock utility
REM --------------------------------------------------------------
if exist \kbdsclk.exe \kbdsclk.exe $$ScreenLock_Param$$

REM ==============================================================
REM Find the RAM drive (if we are using one)
REM
REM This will set the RAM_DRV environment variable to the
REM drive letter of the ram drive or to 'none' if no ram drive.
REM --------------------------------------------------------------
call findramd.bat

REM ==============================================================
REM Find the boot drive
REM
REM This will set the BOOT_DRV environment variable to the
REM drive letter of the boot drive. It will also set the NET
REM variable to the drive letter of the drive containing the
REM network folder. It will also set the SHARE variable.
REM --------------------------------------------------------------

call findboot.bat

echo Booting Drive %BOOT_DRV%...

set PATH=%BOOT_DRV%:\;%net%:\;%net%:\dos;%net%:\net;%ALTIRIS_SHARE%:\;%ALTIRIS_SHARE%:\bootwiz\platfo~1\dos\$$OS$$\os

 

REM ==============================================================
REM Run the detect utility for PCI cards
REM --------------------------------------------------------------
%net%:
cd %net%:\net
if exist %net%:\net\PCIdtect.exe %net%:\net\PCIdtect.exe
cd \
REM Cardsrvc.bat (optional) is manually created by the user and must be placed in the
REM correct driver folder (i.e. myConfig\net\myDriver).  PCIdtect copies it to the
REM net folder (along with the appropriate protocol.ini, system.ini files).
REM The user must specify the name of the card bus services executable file inside cardsrvc.bat
REM and supply Boot Disk Creator with this executable file by adding it to the
REM ""Additional files"" folder or placing it in the ""net"" folder of the configuration.

if exist %net%:\net\cardsrvc.bat call %net%:\net\cardsrvc.bat

REM ==============================================================
REM The following lines contain 'set' environment variables that
REM are use later in the program.  You may wish to change them by
REM simply changing the values or REMing and unREMing them
REM --------------------------------------------------------------

REM ==============================================================
REM Bootwork Variables/Switches
REM --------------------------------------------------------------

REM set DEBUG=-logF:\bootwork.log

REM ==============================================================
REM Network and System Variables
REM --------------------------------------------------------------

set WATTCP.CFG=%net%:\net
set TEMP=%net%:\TEMP

REM ==============================================================
REM See if bootworks should always be run from the share
REM --------------------------------------------------------------

set agentdir=%BOOT_DRV%
$$RunRemoteAgent$$ set agentdir=%ALTIRIS_SHARE%

REM ==============================================================
REM This call to bootworks simple configures the network with
REM information from the Windows client
REM --------------------------------------------------------------

if %agentdir% == %BOOT_DRV% %agentdir%:\bootwork.exe -rs -cfg -nodiag

REM ==============================================================
REM Start the network
REM --------------------------------------------------------------

call startnet.bat

if %ALTIRIS_BOOTTYPE%==NETWORK goto network
goto reload2

:network
$$RemRdeploy$$ rdeploy.exe $$Client$$ $$ClientConfig$$
goto end

:reload2

if exist %net%:\bwscript.bat del %net%:\bwscript.bat > NUL
cls

%agentdir%:\bootwork.exe -rs %DEBUG%

if errorlevel 160 goto reload2
if errorlevel 100 goto boot_production
if not exist %net%:\bwscript.bat goto end
call %net%:\bwscript.bat
goto reload2

REM ==============================================================
REM Production Boot for errorlevel 100.
REM Unload the LAN drivers (logout) then call the dreboot program
REM to quickly boot the local operating system.
REM
REM NOTE:  Normal bootwork execution should not get to this
REM section of the batch file.
REM --------------------------------------------------------------

:boot_production

call stopnet.bat

%BOOT_DRV%:\dreboot.exe -soft

:end

Applies To
All builds of Deployment Solution
HP DC5850 computer
Motherboard 5.1.2600.2180
Hewlett-Packard BIOS 786F6 v02.06, 8/19/2008